DXR is a code search and navigation tool aimed at making sense of large projects. It supports full-text and regex searches as well as structural queries.

Header

Mercurial (41bdd258b79e)

VCS Links

Line Code
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521
/* -*- Mode: C++; tab-width: 20; indent-tabs-mode: nullptr; c-basic-offset: 2 -*-
 * This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

#import "mozilla/layers/NativeLayerCA.h"

#import <QuartzCore/QuartzCore.h>
#import <CoreVideo/CVPixelBuffer.h>

#include <utility>
#include <algorithm>

#include "GLContextCGL.h"
#include "MozFramebuffer.h"
#include "ScopedGLHelpers.h"

@interface CALayer (PrivateSetContentsOpaque)
- (void)setContentsOpaque:(BOOL)opaque;
@end

namespace mozilla {
namespace layers {

using gfx::IntPoint;
using gfx::IntSize;
using gfx::IntRect;
using gfx::IntRegion;

/* static */ already_AddRefed<NativeLayerRootCA> NativeLayerRootCA::CreateForCALayer(
    CALayer* aLayer) {
  RefPtr<NativeLayerRootCA> layerRoot = new NativeLayerRootCA(aLayer);
  return layerRoot.forget();
}

NativeLayerRootCA::NativeLayerRootCA(CALayer* aLayer)
    : mMutex("NativeLayerRootCA"), mRootCALayer([aLayer retain]) {}

NativeLayerRootCA::~NativeLayerRootCA() {
  MOZ_RELEASE_ASSERT(mSublayers.IsEmpty(),
                     "Please clear all layers before destroying the layer root.");

  // FIXME: mMutated might be true at this point, which would indicate that, even
  // though mSublayers is empty now, this state may not yet have been synced to
  // the underlying CALayer. In other words, mRootCALayer might still have sublayers.
  // Should we do anything about that?
  // We could just clear mRootCALayer's sublayers now, but doing so would be a
  // layer tree transformation outside of a transaction, which we want to avoid.
  // But we also don't want to trigger a transaction just for clearing the
  // window's layers. And we wouldn't expect a NativeLayerRootCA to be destroyed
  // while the window is still open and visible. Are layer tree modifications
  // outside of CATransactions allowed while the window is closed? Who knows.

  [mRootCALayer release];
}

already_AddRefed<NativeLayer> NativeLayerRootCA::CreateLayer() {
  RefPtr<NativeLayer> layer = new NativeLayerCA();
  return layer.forget();
}

void NativeLayerRootCA::AppendLayer(NativeLayer* aLayer) {
  MutexAutoLock lock(mMutex);

  RefPtr<NativeLayerCA> layerCA = aLayer->AsNativeLayerCA();
  MOZ_RELEASE_ASSERT(layerCA);

  mSublayers.AppendElement(layerCA);
  layerCA->SetBackingScale(mBackingScale);
  mMutated = true;
}

void NativeLayerRootCA::RemoveLayer(NativeLayer* aLayer) {
  MutexAutoLock lock(mMutex);

  RefPtr<NativeLayerCA> layerCA = aLayer->AsNativeLayerCA();
  MOZ_RELEASE_ASSERT(layerCA);

  mSublayers.RemoveElement(layerCA);
  mMutated = true;
}

// Must be called within a current CATransaction on the transaction's thread.
void NativeLayerRootCA::ApplyChanges() {
  MutexAutoLock lock(mMutex);

  [CATransaction setDisableActions:YES];

  // Call ApplyChanges on our sublayers first, and then update the root layer's
  // list of sublayers. The order is important because we need layer->UnderlyingCALayer()
  // to be non-null, and the underlying CALayer gets lazily initialized in ApplyChanges().
  for (auto layer : mSublayers) {
    layer->ApplyChanges();
  }

  if (mMutated) {
    NSMutableArray<CALayer*>* sublayers = [NSMutableArray arrayWithCapacity:mSublayers.Length()];
    for (auto layer : mSublayers) {
      [sublayers addObject:layer->UnderlyingCALayer()];
    }
    mRootCALayer.sublayers = sublayers;
    mMutated = false;
  }
}

void NativeLayerRootCA::SetBackingScale(float aBackingScale) {
  MutexAutoLock lock(mMutex);

  mBackingScale = aBackingScale;
  for (auto layer : mSublayers) {
    layer->SetBackingScale(aBackingScale);
  }
}

NativeLayerCA::NativeLayerCA() : mMutex("NativeLayerCA") {}

NativeLayerCA::~NativeLayerCA() {
  SetSurfaceRegistry(nullptr);  // or maybe MOZ_RELEASE_ASSERT(!mSurfaceRegistry) would be better?

  if (mInProgressLockedIOSurface) {
    mInProgressLockedIOSurface->Unlock(false);
    mInProgressLockedIOSurface = nullptr;
  }
  if (mInProgressSurface) {
    IOSurfaceDecrementUseCount(mInProgressSurface->mSurface.get());
  }
  if (mReadySurface) {
    IOSurfaceDecrementUseCount(mReadySurface->mSurface.get());
  }

  for (CALayer* contentLayer : mContentCALayers) {
    [contentLayer release];
  }
  [mWrappingCALayer release];
}

void NativeLayerCA::SetSurfaceRegistry(RefPtr<IOSurfaceRegistry> aSurfaceRegistry) {
  MutexAutoLock lock(mMutex);

  if (mSurfaceRegistry) {
    for (auto surf : mSurfaces) {
      mSurfaceRegistry->UnregisterSurface(surf.mSurface);
    }
    if (mInProgressSurface) {
      mSurfaceRegistry->UnregisterSurface(mInProgressSurface->mSurface);
    }
    if (mReadySurface) {
      mSurfaceRegistry->UnregisterSurface(mReadySurface->mSurface);
    }
  }
  mSurfaceRegistry = aSurfaceRegistry;
  if (mSurfaceRegistry) {
    for (auto surf : mSurfaces) {
      mSurfaceRegistry->RegisterSurface(surf.mSurface);
    }
    if (mInProgressSurface) {
      mSurfaceRegistry->RegisterSurface(mInProgressSurface->mSurface);
    }
    if (mReadySurface) {
      mSurfaceRegistry->RegisterSurface(mReadySurface->mSurface);
    }
  }
}

RefPtr<IOSurfaceRegistry> NativeLayerCA::GetSurfaceRegistry() {
  MutexAutoLock lock(mMutex);

  return mSurfaceRegistry;
}

void NativeLayerCA::SetSurfaceIsFlipped(bool aIsFlipped) {
  MutexAutoLock lock(mMutex);

  if (aIsFlipped != mSurfaceIsFlipped) {
    mSurfaceIsFlipped = aIsFlipped;
    mMutatedGeometry = true;
  }
}

bool NativeLayerCA::SurfaceIsFlipped() {
  MutexAutoLock lock(mMutex);

  return mSurfaceIsFlipped;
}

void NativeLayerCA::SetRect(const IntRect& aRect) {
  MutexAutoLock lock(mMutex);

  if (aRect.TopLeft() != mPosition) {
    mPosition = aRect.TopLeft();
    mMutatedPosition = true;
  }
  if (aRect.Size() != mSize) {
    mSize = aRect.Size();
    mMutatedGeometry = true;
  }
}

IntRect NativeLayerCA::GetRect() {
  MutexAutoLock lock(mMutex);
  return IntRect(mPosition, mSize);
}

void NativeLayerCA::SetBackingScale(float aBackingScale) {
  MutexAutoLock lock(mMutex);

  if (aBackingScale != mBackingScale) {
    mBackingScale = aBackingScale;
    mMutatedGeometry = true;
  }
}

void NativeLayerCA::SetOpaqueRegion(const gfx::IntRegion& aRegion) {
  MutexAutoLock lock(mMutex);

  if (aRegion != mOpaqueRegion) {
    mOpaqueRegion = aRegion;
    mMutatedGeometry = true;
  }
}

gfx::IntRegion NativeLayerCA::OpaqueRegion() {
  MutexAutoLock lock(mMutex);
  return mOpaqueRegion;
}

IntRegion NativeLayerCA::CurrentSurfaceInvalidRegion() {
  MutexAutoLock lock(mMutex);

  MOZ_RELEASE_ASSERT(
      mInProgressSurface,
      "Only call currentSurfaceInvalidRegion after a call to NextSurface and before the call "
      "to notifySurfaceIsReady.");
  return mInProgressSurface->mInvalidRegion;
}

void NativeLayerCA::InvalidateRegionThroughoutSwapchain(const IntRegion& aRegion) {
  MutexAutoLock lock(mMutex);

  IntRegion r = aRegion;
  r.AndWith(IntRect(IntPoint(0, 0), mSize));
  if (mInProgressSurface) {
    mInProgressSurface->mInvalidRegion.OrWith(r);
  }
  if (mReadySurface) {
    mReadySurface->mInvalidRegion.OrWith(r);
  }
  for (auto& surf : mSurfaces) {
    surf.mInvalidRegion.OrWith(r);
  }
}

CFTypeRefPtr<IOSurfaceRef> NativeLayerCA::NextSurface() {
  MutexAutoLock lock(mMutex);
  return NextSurfaceLocked(lock);
}

CFTypeRefPtr<IOSurfaceRef> NativeLayerCA::NextSurfaceLocked(const MutexAutoLock& aLock) {
  IntSize surfaceSize = mSize;
  if (surfaceSize.IsEmpty()) {
    NSLog(@"NextSurface returning nullptr because of invalid surfaceSize (%d, %d).",
          surfaceSize.width, surfaceSize.height);
    return nullptr;
  }

  MOZ_RELEASE_ASSERT(
      !mInProgressSurface,
      "ERROR: Do not call NextSurface twice in sequence. Call NotifySurfaceReady before the "
      "next call to NextSurface.");

  // Find the last surface in unusedSurfaces which has the right size. If such
  // a surface exists, it is the surface we will recycle.
  std::vector<SurfaceWithInvalidRegion> unusedSurfaces = RemoveExcessUnusedSurfaces(aLock);
  auto surfIter = std::find_if(
      unusedSurfaces.rbegin(), unusedSurfaces.rend(),
      [surfaceSize](const SurfaceWithInvalidRegion& s) { return s.mSize == surfaceSize; });

  Maybe<SurfaceWithInvalidRegion> surf;
  if (surfIter != unusedSurfaces.rend()) {
    // We found the surface we want to recycle.
    surf = Some(*surfIter);

    // Remove surf from unusedSurfaces.
    // The reverse iterator makes this a bit cumbersome.
    unusedSurfaces.erase(std::next(surfIter).base());
  } else {
    CFTypeRefPtr<IOSurfaceRef> newSurf = CFTypeRefPtr<IOSurfaceRef>::WrapUnderCreateRule(
        IOSurfaceCreate((__bridge CFDictionaryRef) @{
          (__bridge NSString*)kIOSurfaceWidth : @(surfaceSize.width),
          (__bridge NSString*)kIOSurfaceHeight : @(surfaceSize.height),
          (__bridge NSString*)kIOSurfacePixelFormat : @(kCVPixelFormatType_32BGRA),
          (__bridge NSString*)kIOSurfaceBytesPerElement : @(4),
        }));
    if (!newSurf) {
      NSLog(@"NextSurface returning nullptr because IOSurfaceCreate failed to create the surface.");
      return nullptr;
    }
    if (mSurfaceRegistry) {
      mSurfaceRegistry->RegisterSurface(newSurf);
    }
    surf =
        Some(SurfaceWithInvalidRegion{newSurf, IntRect(IntPoint(0, 0), surfaceSize), surfaceSize});
  }

  // Delete all other unused surfaces.
  for (auto unusedSurf : unusedSurfaces) {
    if (mSurfaceRegistry) {
      mSurfaceRegistry->UnregisterSurface(unusedSurf.mSurface);
    }
    mFramebuffers.erase(unusedSurf.mSurface);
  }
  unusedSurfaces.clear();

  MOZ_RELEASE_ASSERT(surf);
  mInProgressSurface = std::move(surf);
  IOSurfaceIncrementUseCount(mInProgressSurface->mSurface.get());
  return mInProgressSurface->mSurface;
}

RefPtr<gfx::DrawTarget> NativeLayerCA::NextSurfaceAsDrawTarget(gfx::BackendType aBackendType) {
  MutexAutoLock lock(mMutex);
  CFTypeRefPtr<IOSurfaceRef> surface = NextSurfaceLocked(lock);
  if (!surface) {
    return nullptr;
  }

  mInProgressLockedIOSurface = new MacIOSurface(std::move(surface));
  mInProgressLockedIOSurface->Lock(false);
  return mInProgressLockedIOSurface->GetAsDrawTargetLocked(aBackendType);
}

void NativeLayerCA::SetGLContext(gl::GLContext* aContext) {
  MutexAutoLock lock(mMutex);

  RefPtr<gl::GLContextCGL> glContextCGL = gl::GLContextCGL::Cast(aContext);
  MOZ_RELEASE_ASSERT(glContextCGL, "Unexpected GLContext type");

  if (glContextCGL != mGLContext) {
    mFramebuffers.clear();
    mGLContext = glContextCGL;
  }
}

gl::GLContext* NativeLayerCA::GetGLContext() {
  MutexAutoLock lock(mMutex);
  return mGLContext;
}

Maybe<GLuint> NativeLayerCA::NextSurfaceAsFramebuffer(bool aNeedsDepth) {
  MutexAutoLock lock(mMutex);
  CFTypeRefPtr<IOSurfaceRef> surface = NextSurfaceLocked(lock);
  if (!surface) {
    return Nothing();
  }

  return Some(GetOrCreateFramebufferForSurface(lock, std::move(surface), aNeedsDepth));
}

GLuint NativeLayerCA::GetOrCreateFramebufferForSurface(const MutexAutoLock&,
                                                       CFTypeRefPtr<IOSurfaceRef> aSurface,
                                                       bool aNeedsDepth) {
  auto fbCursor = mFramebuffers.find(aSurface);
  if (fbCursor != mFramebuffers.end()) {
    return fbCursor->second->mFB;
  }

  MOZ_RELEASE_ASSERT(
      mGLContext, "Only call NextSurfaceAsFramebuffer when a GLContext is set on this NativeLayer");
  mGLContext->MakeCurrent();
  GLuint tex = mGLContext->CreateTexture();
  {
    const gl::ScopedBindTexture bindTex(mGLContext, tex, LOCAL_GL_TEXTURE_RECTANGLE_ARB);
    CGLTexImageIOSurface2D(mGLContext->GetCGLContext(), LOCAL_GL_TEXTURE_RECTANGLE_ARB,
                           LOCAL_GL_RGBA, mSize.width, mSize.height, LOCAL_GL_BGRA,
                           LOCAL_GL_UNSIGNED_INT_8_8_8_8_REV, aSurface.get(), 0);
  }

  auto fb = gl::MozFramebuffer::CreateWith(mGLContext, mSize, 0, aNeedsDepth,
                                           LOCAL_GL_TEXTURE_RECTANGLE_ARB, tex);
  GLuint fbo = fb->mFB;
  mFramebuffers.insert({aSurface, std::move(fb)});

  return fbo;
}

void NativeLayerCA::NotifySurfaceReady() {
  MutexAutoLock lock(mMutex);

  MOZ_RELEASE_ASSERT(mInProgressSurface,
                     "NotifySurfaceReady called without preceding call to NextSurface");
  if (mReadySurface) {
    IOSurfaceDecrementUseCount(mReadySurface->mSurface.get());
    mSurfaces.push_back(*mReadySurface);
    mReadySurface = Nothing();
  }

  if (mInProgressLockedIOSurface) {
    mInProgressLockedIOSurface->Unlock(false);
    mInProgressLockedIOSurface = nullptr;
  }

  mReadySurface = std::move(mInProgressSurface);
  mReadySurface->mInvalidRegion = IntRect();
}

void NativeLayerCA::ApplyChanges() {
  MutexAutoLock lock(mMutex);

  if (!mWrappingCALayer) {
    mWrappingCALayer = [[CALayer layer] retain];
    mWrappingCALayer.position = NSZeroPoint;
    mWrappingCALayer.bounds = NSZeroRect;
    mWrappingCALayer.anchorPoint = NSZeroPoint;
    mWrappingCALayer.contentsGravity = kCAGravityTopLeft;
  }

  if (mMutatedPosition || mMutatedGeometry) {
    mWrappingCALayer.position =
        CGPointMake(mPosition.x / mBackingScale, mPosition.y / mBackingScale);
    mMutatedPosition = false;
  }

  if (mMutatedGeometry) {
    mWrappingCALayer.bounds =
        CGRectMake(0, 0, mSize.width / mBackingScale, mSize.height / mBackingScale);

    // Assemble opaque and transparent sublayers to cover the respective regions.
    // mContentCALayers has the current sublayers. We will try to re-use layers
    // as much as possible.
    IntRegion opaqueRegion;
    opaqueRegion.And(IntRect(IntPoint(), mSize), mOpaqueRegion);
    IntRegion transparentRegion;
    transparentRegion.Sub(IntRect(IntPoint(), mSize), opaqueRegion);
    std::deque<CALayer*> layersToRecycle = std::move(mContentCALayers);
    PlaceContentLayers(lock, opaqueRegion, true, &layersToRecycle);
    PlaceContentLayers(lock, transparentRegion, false, &layersToRecycle);
    for (CALayer* unusedLayer : layersToRecycle) {
      [unusedLayer release];
    }
    NSMutableArray<CALayer*>* sublayers =
        [NSMutableArray arrayWithCapacity:mContentCALayers.size()];
    for (auto layer : mContentCALayers) {
      [sublayers addObject:layer];
    }
    mWrappingCALayer.sublayers = sublayers;
    mMutatedGeometry = false;
  }

  if (mReadySurface) {
    for (CALayer* layer : mContentCALayers) {
      layer.contents = (id)mReadySurface->mSurface.get();
    }
    IOSurfaceDecrementUseCount(mReadySurface->mSurface.get());
    mSurfaces.push_back(*mReadySurface);
    mReadySurface = Nothing();
  }
}

void NativeLayerCA::PlaceContentLayers(const MutexAutoLock&, const IntRegion& aRegion, bool aOpaque,
                                       std::deque<CALayer*>* aLayersToRecycle) {
  for (auto iter = aRegion.RectIter(); !iter.Done(); iter.Next()) {
    IntRect r = iter.Get();

    CALayer* layer;
    if (aLayersToRecycle->empty()) {
      layer = [[CALayer layer] retain];
      layer.anchorPoint = NSZeroPoint;
      layer.contentsGravity = kCAGravityTopLeft;
    } else {
      layer = aLayersToRecycle->front();
      aLayersToRecycle->pop_front();
    }
    layer.position = CGPointMake(r.x / mBackingScale, r.y / mBackingScale);
    layer.bounds = CGRectMake(0, 0, r.width / mBackingScale, r.height / mBackingScale);
    layer.contentsScale = mBackingScale;
    CGRect unitContentsRect =
        CGRectMake(CGFloat(r.x) / mSize.width, CGFloat(r.y) / mSize.height,
                   CGFloat(r.width) / mSize.width, CGFloat(r.height) / mSize.height);
    if (mSurfaceIsFlipped) {
      CGFloat height = r.height / mBackingScale;
      layer.affineTransform = CGAffineTransformMake(1.0, 0.0, 0.0, -1.0, 0.0, height);
      unitContentsRect.origin.y = 1.0 - (unitContentsRect.origin.y + unitContentsRect.size.height);
      layer.contentsRect = unitContentsRect;
    } else {
      layer.affineTransform = CGAffineTransformIdentity;
      layer.contentsRect = unitContentsRect;
    }
    layer.opaque = aOpaque;
    if ([layer respondsToSelector:@selector(setContentsOpaque:)]) {
      // The opaque property seems to not be enough when using IOSurface contents.
      // Additionally, call the private method setContentsOpaque.
      [layer setContentsOpaque:aOpaque];
    }
    mContentCALayers.push_back(layer);
  }
}

// Called when mMutex is already being held by the current thread.
std::vector<NativeLayerCA::SurfaceWithInvalidRegion> NativeLayerCA::RemoveExcessUnusedSurfaces(
    const MutexAutoLock&) {
  std::vector<SurfaceWithInvalidRegion> usedSurfaces;
  std::vector<SurfaceWithInvalidRegion> unusedSurfaces;

  // Separate mSurfaces into used and unused surfaces, leaving 2 surfaces behind.
  while (mSurfaces.size() > 2) {
    auto surf = std::move(mSurfaces.front());
    mSurfaces.pop_front();
    if (IOSurfaceIsInUse(surf.mSurface.get())) {
      usedSurfaces.push_back(std::move(surf));
    } else {
      unusedSurfaces.push_back(std::move(surf));
    }
  }
  // Put the used surfaces back into mSurfaces, at the beginning.
  mSurfaces.insert(mSurfaces.begin(), usedSurfaces.begin(), usedSurfaces.end());

  return unusedSurfaces;
}

}  // namespace layers
}  // namespace mozilla