DXR is a code search and navigation tool aimed at making sense of large projects. It supports full-text and regex searches as well as structural queries.

Mercurial (273c3db836e1)

VCS Links

Line Code
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94
/* -*- Mode: C++; tab-width: 8; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

include "mozilla/dom/MediaIPCUtils.h";

include protocol PRemoteDecoderManager;

using mozilla::MediaDataDecoder::ConversionRequired from "PlatformDecoderModule.h";
using mozilla::TrackInfo::TrackType from "MediaInfo.h";
using mozilla::layers::LayersBackend from "mozilla/layers/LayersTypes.h";
using mozilla::MediaResult from "MediaResult.h";

include PMediaDecoderParams;
include LayersSurfaces;

namespace mozilla {

struct RemoteVideoDataIPDL
{
  MediaDataIPDL base;
  IntSize display;
  IntSize frameSize;
  SurfaceDescriptor sd;
  int32_t frameID;
};

struct RemoteAudioDataIPDL
{
  MediaDataIPDL base;
  uint32_t channels;
  uint32_t rate;
  uint32_t channelMap;
  // Pass along buffer size since we're using ShmemPool
  // and we can receive buffers larger than requested size.
  int64_t audioDataBufferSize;
  Shmem buffer;
};

union DecodedOutputIPDL
{
  RemoteAudioDataIPDL[];
  RemoteVideoDataIPDL[];
};

struct InitCompletionIPDL
{
  TrackType type;
  nsCString decoderDescription;
  bool hardware;
  nsCString hardwareReason;
  ConversionRequired conversion;
};

union InitResultIPDL
{
  MediaResult;
  InitCompletionIPDL;
};

union DecodeResultIPDL
{
  MediaResult;
  DecodedOutputIPDL;
};

// This protocol provides a way to use MediaDataDecoder across processes.
// The parent side currently is only implemented to work with
// RemoteDecoderModule or WindowsMediaFoundation.
// The child side runs in the content process, and the parent side runs
// in the RDD process or the GPU process. We run a separate IPDL thread
// for both sides.
async protocol PRemoteDecoder
{
  manager PRemoteDecoderManager;
parent:
  async Init() returns (InitResultIPDL result);

  // Each output may include a SurfaceDescriptorGPUVideo that represents the decoded
  // frame. This SurfaceDescriptor can be used on the Layers IPDL protocol, but
  // must be released explicitly using DeallocateSurfaceDescriptorGPUVideo
  // on the manager protocol.
  async Decode(MediaRawDataIPDL data) returns (DecodeResultIPDL result);
  async Flush() returns (MediaResult error);
  async Drain() returns (DecodeResultIPDL result);
  async Shutdown() returns (bool unused);
  // To clear the threshold, call with INT64_MIN.
  async SetSeekThreshold(TimeUnit time);

  async __delete__();
};

} // namespace mozilla