DXR is a code search and navigation tool aimed at making sense of large projects. It supports full-text and regex searches as well as structural queries.

Header

Mercurial (b6057e17f856)

VCS Links

Line Code
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511
/* -*- Mode: C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
// vim:set ts=2 sts=2 sw=2 et cin:
/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

#include <dlfcn.h>
#import <AppKit/AppKit.h>
#import <QuartzCore/QuartzCore.h>
#include "PluginUtilsOSX.h"

// Remove definitions for try/catch interfering with ObjCException macros.
#include "nsObjCExceptions.h"
#include "nsCocoaUtils.h"

#include "nsDebug.h"

@interface CALayer (ContentsScale)
- (double)contentsScale;
- (void)setContentsScale:(double)scale;
@end

using namespace mozilla::plugins::PluginUtilsOSX;

@interface CGBridgeLayer : CALayer {
  DrawPluginFunc mDrawFunc;
  void* mPluginInstance;
  nsIntRect mUpdateRect;
  BOOL mAvoidCGCrashes;
  CGContextRef mLastCGContext;
}
- (void)setDrawFunc:(DrawPluginFunc)aFunc
     pluginInstance:(void*)aPluginInstance
     avoidCGCrashes:(BOOL)aAvoidCGCrashes;
- (void)updateRect:(nsIntRect)aRect;
- (void)protectLastCGContext;

@end

// CGBitmapContextSetData() is an undocumented function present (with
// the same signature) since at least OS X 10.5.  As the name suggests,
// it's used to replace the "data" in a bitmap context that was
// originally specified in a call to CGBitmapContextCreate() or
// CGBitmapContextCreateWithData().
typedef void (*CGBitmapContextSetDataFunc) (CGContextRef c,
                                            size_t x,
                                            size_t y,
                                            size_t width,
                                            size_t height,
                                            void* data,
                                            size_t bitsPerComponent,
                                            size_t bitsPerPixel,
                                            size_t bytesPerRow);
CGBitmapContextSetDataFunc CGBitmapContextSetDataPtr = NULL;

@implementation CGBridgeLayer
- (void) updateRect:(nsIntRect)aRect
{
   mUpdateRect.UnionRect(mUpdateRect, aRect);
}

- (void) setDrawFunc:(DrawPluginFunc)aFunc
      pluginInstance:(void*)aPluginInstance
      avoidCGCrashes:(BOOL)aAvoidCGCrashes
{
  mDrawFunc = aFunc;
  mPluginInstance = aPluginInstance;
  mAvoidCGCrashes = aAvoidCGCrashes;
  mLastCGContext = nil;
}

// The Flash plugin, in very unusual circumstances, can (in CoreGraphics
// mode) try to access the CGContextRef from -[CGBridgeLayer drawInContext:]
// outside of any call to NPP_HandleEvent(NPCocoaEventDrawRect).  This usually
// crashes the plugin process (probably because it tries to access deleted
// memory).  We stop these crashes from happening by holding a reference to
// the CGContextRef, and also by ensuring that it's data won't get deleted.
// The CGContextRef won't "work" in this form.  But this won't cause trouble
// for plugins that do things correctly (that don't access this CGContextRef
// outside of the call to NPP_HandleEvent() that passes it to the plugin).
// The OS may reuse this CGContextRef (it may get passed to other calls to
// -[CGBridgeLayer drawInContext:]).  But before each call the OS calls
// CGBitmapContextSetData() to replace its data, which undoes the changes
// we make here.  See bug 804606.
- (void)protectLastCGContext
{
  if (!mAvoidCGCrashes || !mLastCGContext) {
    return;
  }

  static char ensuredData[128] = {0};

  if (!CGBitmapContextSetDataPtr) {
    CGBitmapContextSetDataPtr = (CGBitmapContextSetDataFunc)
      dlsym(RTLD_DEFAULT, "CGBitmapContextSetData");
  }

  if (CGBitmapContextSetDataPtr && (GetContextType(mLastCGContext) == CG_CONTEXT_TYPE_BITMAP)) {
    CGBitmapContextSetDataPtr(mLastCGContext, 0, 0, 1, 1, ensuredData, 8, 32, 64);
  }
}

- (void)drawInContext:(CGContextRef)aCGContext
{
  ::CGContextSaveGState(aCGContext); 
  ::CGContextTranslateCTM(aCGContext, 0, self.bounds.size.height);
  ::CGContextScaleCTM(aCGContext, (CGFloat) 1, (CGFloat) -1);

  mUpdateRect = nsIntRect(0, 0, self.bounds.size.width, self.bounds.size.height);

  mDrawFunc(aCGContext, mPluginInstance, mUpdateRect);

  ::CGContextRestoreGState(aCGContext);

  if (mAvoidCGCrashes) {
    if (mLastCGContext) {
      ::CGContextRelease(mLastCGContext);
    }
    mLastCGContext = aCGContext;
    ::CGContextRetain(mLastCGContext);
  }

  mUpdateRect.SetEmpty();
}

- (void)dealloc
{
  if (mLastCGContext) {
    ::CGContextRelease(mLastCGContext);
  }
  [super dealloc];
}

@end

void* mozilla::plugins::PluginUtilsOSX::GetCGLayer(DrawPluginFunc aFunc, void* aPluginInstance,
                                                   bool aAvoidCGCrashes, double aContentsScaleFactor)
{
  CGBridgeLayer *bridgeLayer = [[CGBridgeLayer alloc] init];

  // We need to make bridgeLayer behave properly when its superlayer changes
  // size (in nsCARenderer::SetBounds()).
  bridgeLayer.autoresizingMask = kCALayerWidthSizable | kCALayerHeightSizable;
  bridgeLayer.needsDisplayOnBoundsChange = YES;
  NSNull *nullValue = [NSNull null];
  NSDictionary *actions = [NSDictionary dictionaryWithObjectsAndKeys:
                             nullValue, @"bounds",
                             nullValue, @"contents",
                             nullValue, @"contentsRect",
                             nullValue, @"position",
                             nil];
  [bridgeLayer setStyle:[NSDictionary dictionaryWithObject:actions forKey:@"actions"]];

  // For reasons that aren't clear (perhaps one or more OS bugs), we can only
  // use full HiDPI resolution here if the tree is built with the 10.7 SDK or
  // up.  If we build with the 10.6 SDK, changing the contentsScale property
  // of bridgeLayer (even to the same value) causes it to stop working (go
  // blank).  This doesn't happen with objects that are members of the CALayer
  // class (as opposed to one of its subclasses).
#if defined(MAC_OS_X_VERSION_10_7) && \
    MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_7
  if ([bridgeLayer respondsToSelector:@selector(setContentsScale:)]) {
    bridgeLayer.contentsScale = aContentsScaleFactor;
  }
#endif

  [bridgeLayer setDrawFunc:aFunc
            pluginInstance:aPluginInstance
            avoidCGCrashes:aAvoidCGCrashes];
  return bridgeLayer;
}

void mozilla::plugins::PluginUtilsOSX::ReleaseCGLayer(void *cgLayer) {
  CGBridgeLayer *bridgeLayer = (CGBridgeLayer*)cgLayer;
  [bridgeLayer release];
}

void mozilla::plugins::PluginUtilsOSX::Repaint(void *caLayer, nsIntRect aRect) {
  CGBridgeLayer *bridgeLayer = (CGBridgeLayer*)caLayer;
  [CATransaction begin];
  [bridgeLayer updateRect:aRect];
  [bridgeLayer setNeedsDisplay];
  [bridgeLayer displayIfNeeded];
  [CATransaction commit];
  [bridgeLayer protectLastCGContext];
}

@interface EventProcessor : NSObject {
  RemoteProcessEvents   aRemoteEvents;
  void                 *aPluginModule;
}
- (void)setRemoteEvents:(RemoteProcessEvents) remoteEvents pluginModule:(void*) pluginModule;
- (void)onTick;
@end

@implementation EventProcessor
- (void) onTick
{
    aRemoteEvents(aPluginModule);
}

- (void)setRemoteEvents:(RemoteProcessEvents) remoteEvents pluginModule:(void*) pluginModule
{
    aRemoteEvents = remoteEvents;
    aPluginModule = pluginModule;
}
@end

#define EVENT_PROCESS_DELAY 0.05 // 50 ms

NPError mozilla::plugins::PluginUtilsOSX::ShowCocoaContextMenu(void* aMenu, int aX, int aY, void* pluginModule, RemoteProcessEvents remoteEvent) 
{
  NS_OBJC_BEGIN_TRY_ABORT_BLOCK;

  // Set the native cursor to the OS default (an arrow) before displaying the
  // context menu.  Otherwise (if the plugin has changed the cursor) it may
  // stay as the plugin has set it -- which means it may be invisible.  We
  // need to do this because we display the context menu without making the
  // plugin process the foreground process.  If we did, the cursor would
  // change to an arrow cursor automatically -- as it does in Chrome.
  [[NSCursor arrowCursor] set];

  // Create a timer to process browser events while waiting
  // on the menu. This prevents the browser from hanging
  // during the lifetime of the menu.
  EventProcessor* eventProcessor = [[EventProcessor alloc] init];
  [eventProcessor setRemoteEvents:remoteEvent pluginModule:pluginModule];
  NSTimer *eventTimer = [NSTimer timerWithTimeInterval:EVENT_PROCESS_DELAY
                             target:eventProcessor selector:@selector(onTick) 
                             userInfo:nil repeats:TRUE];
  // Use NSEventTrackingRunLoopMode otherwise the timer will
  // not fire during the right click menu.
  [[NSRunLoop currentRunLoop] addTimer:eventTimer 
                              forMode:NSEventTrackingRunLoopMode];

  NSMenu* nsmenu = reinterpret_cast<NSMenu*>(aMenu);
  NSPoint screen_point = ::NSMakePoint(aX, aY);

  [nsmenu popUpMenuPositioningItem:nil atLocation:screen_point inView:nil];

  [eventTimer invalidate];
  [eventProcessor release];

  return NPERR_NO_ERROR;

  NS_OBJC_END_TRY_ABORT_BLOCK_RETURN(NPERR_GENERIC_ERROR);
}

void mozilla::plugins::PluginUtilsOSX::InvokeNativeEventLoop()
{
  NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
  ::CFRunLoopRunInMode(kCFRunLoopDefaultMode, 0.0, true);
  NS_OBJC_END_TRY_ABORT_BLOCK;
}


#define UNDOCUMENTED_SESSION_CONSTANT ((int)-2)
namespace mozilla {
namespace plugins {
namespace PluginUtilsOSX {
  static void *sApplicationASN = NULL;
  static void *sApplicationInfoItem = NULL;
}
}
}

bool mozilla::plugins::PluginUtilsOSX::SetProcessName(const char* aProcessName) {
  NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
  nsAutoreleasePool localPool;

  if (!aProcessName || strcmp(aProcessName, "") == 0) {
    return false;
  }

  NSString *currentName = [[[NSBundle mainBundle] localizedInfoDictionary] 
                              objectForKey:(NSString *)kCFBundleNameKey];

  char formattedName[1024];
  snprintf(formattedName, sizeof(formattedName), 
      "%s (%s)", [currentName UTF8String], aProcessName);

  aProcessName = formattedName;

  // This function is based on Chrome/Webkit's and relies on potentially dangerous SPI.
  typedef CFTypeRef (*LSGetASNType)();
  typedef OSStatus (*LSSetInformationItemType)(int, CFTypeRef,
                                               CFStringRef, 
                                               CFStringRef,
                                               CFDictionaryRef*);

  CFBundleRef launchServices = ::CFBundleGetBundleWithIdentifier(
                                          CFSTR("com.apple.LaunchServices"));
  if (!launchServices) {
    NS_WARNING("Failed to set process name: Could not open LaunchServices bundle");
    return false;
  }

  if (!sApplicationASN) {
    sApplicationASN = ::CFBundleGetFunctionPointerForName(launchServices, 
                                            CFSTR("_LSGetCurrentApplicationASN"));
  }

  LSGetASNType getASNFunc = reinterpret_cast<LSGetASNType>
                                          (sApplicationASN);

  if (!sApplicationInfoItem) {
    sApplicationInfoItem = ::CFBundleGetFunctionPointerForName(launchServices, 
                                            CFSTR("_LSSetApplicationInformationItem"));
  }

  LSSetInformationItemType setInformationItemFunc 
                                          = reinterpret_cast<LSSetInformationItemType>
                                          (sApplicationInfoItem);

  void * displayNameKeyAddr = ::CFBundleGetDataPointerForName(launchServices,
                                          CFSTR("_kLSDisplayNameKey"));

  CFStringRef displayNameKey = nil;
  if (displayNameKeyAddr) {
    displayNameKey = reinterpret_cast<CFStringRef>(*(CFStringRef*)displayNameKeyAddr);
  }

  // Rename will fail without this
  ProcessSerialNumber psn;
  if (::GetCurrentProcess(&psn) != noErr) {
    return false;
  }

  CFTypeRef currentAsn = getASNFunc();

  if (!getASNFunc || !setInformationItemFunc || 
      !displayNameKey || !currentAsn) {
    NS_WARNING("Failed to set process name: Accessing launchServices failed");
    return false;
  }

  CFStringRef processName = ::CFStringCreateWithCString(nil, 
                                                        aProcessName, 
                                                        kCFStringEncodingASCII);
  if (!processName) {
    NS_WARNING("Failed to set process name: Could not create CFStringRef");
    return false;
  }

  OSErr err = setInformationItemFunc(UNDOCUMENTED_SESSION_CONSTANT, currentAsn,
                                     displayNameKey, processName,
                                     nil); // Optional out param
  ::CFRelease(processName);
  if (err != noErr) {
    NS_WARNING("Failed to set process name: LSSetInformationItemType err");
    return false;
  }

  return true;
  NS_OBJC_END_TRY_ABORT_BLOCK_RETURN(false);
}

namespace mozilla {
namespace plugins {
namespace PluginUtilsOSX {

size_t nsDoubleBufferCARenderer::GetFrontSurfaceWidth() {
  if (!HasFrontSurface()) {
    return 0;
  }

  return mFrontSurface->GetWidth();
}

size_t nsDoubleBufferCARenderer::GetFrontSurfaceHeight() {
  if (!HasFrontSurface()) {
    return 0;
  }

  return mFrontSurface->GetHeight();
}

double nsDoubleBufferCARenderer::GetFrontSurfaceContentsScaleFactor() {
  if (!HasFrontSurface()) {
    return 1.0;
  }

  return mFrontSurface->GetContentsScaleFactor();
}

size_t nsDoubleBufferCARenderer::GetBackSurfaceWidth() {
  if (!HasBackSurface()) {
    return 0;
  }

  return mBackSurface->GetWidth();
}

size_t nsDoubleBufferCARenderer::GetBackSurfaceHeight() {
  if (!HasBackSurface()) {
    return 0;
  }

  return mBackSurface->GetHeight();
}

double nsDoubleBufferCARenderer::GetBackSurfaceContentsScaleFactor() {
  if (!HasBackSurface()) {
    return 1.0;
  }

  return mBackSurface->GetContentsScaleFactor();
}

IOSurfaceID nsDoubleBufferCARenderer::GetFrontSurfaceID() {
  if (!HasFrontSurface()) {
    return 0;
  }

  return mFrontSurface->GetIOSurfaceID();
}

bool nsDoubleBufferCARenderer::HasBackSurface() {
  return !!mBackSurface;
}

bool nsDoubleBufferCARenderer::HasFrontSurface() {
  return !!mFrontSurface;
}

bool nsDoubleBufferCARenderer::HasCALayer() {
  return !!mCALayer;
}

void nsDoubleBufferCARenderer::SetCALayer(void *aCALayer) {
  mCALayer = aCALayer;
}

bool nsDoubleBufferCARenderer::InitFrontSurface(size_t aWidth, size_t aHeight,
                                                double aContentsScaleFactor,
                                                AllowOfflineRendererEnum aAllowOfflineRenderer) {
  if (!mCALayer) {
    return false;
  }

  mContentsScaleFactor = aContentsScaleFactor;
  mFrontSurface = MacIOSurface::CreateIOSurface(aWidth, aHeight, mContentsScaleFactor);
  if (!mFrontSurface) {
    mCARenderer = nullptr;
    return false;
  }

  if (!mCARenderer) {
    mCARenderer = new nsCARenderer();
    if (!mCARenderer) {
      mFrontSurface = nullptr;
      return false;
    }

    mCARenderer->AttachIOSurface(mFrontSurface);

    nsresult result = mCARenderer->SetupRenderer(mCALayer,
                        mFrontSurface->GetWidth(),
                        mFrontSurface->GetHeight(),
                        mContentsScaleFactor,
                        aAllowOfflineRenderer);

    if (result != NS_OK) {
      mCARenderer = nullptr;
      mFrontSurface = nullptr;
      return false;
    }
  } else {
    mCARenderer->AttachIOSurface(mFrontSurface);
  }

  return true;
}

void nsDoubleBufferCARenderer::Render() {
  if (!HasFrontSurface() || !mCARenderer) {
    return;
  }

  mCARenderer->Render(GetFrontSurfaceWidth(), GetFrontSurfaceHeight(),
                      mContentsScaleFactor, nullptr);
}

void nsDoubleBufferCARenderer::SwapSurfaces() {
  RefPtr<MacIOSurface> prevFrontSurface = mFrontSurface;
  mFrontSurface = mBackSurface;
  mBackSurface = prevFrontSurface;

  if (mFrontSurface) {
    mCARenderer->AttachIOSurface(mFrontSurface);
  }
}

void nsDoubleBufferCARenderer::ClearFrontSurface() {
  mFrontSurface = nullptr;
  if (!mFrontSurface && !mBackSurface) {
    mCARenderer = nullptr;
  }
}

void nsDoubleBufferCARenderer::ClearBackSurface() {
  mBackSurface = nullptr;
  if (!mFrontSurface && !mBackSurface) {
    mCARenderer = nullptr;
  }
}

} //PluginUtilsOSX
} //plugins
} //mozilla